class NsSearchResult

La classe NsSearchResult décrit de manière générique un fichier issu d'une recherche utilisant la classe NsSearchEngine.

ID : __int64 readonly

L'identificateur unique du fichier (NsBackupFile).

VersionID : __int64 readonly

L'identificateur unique de la dernière version du fichier liée.

SourceID : __int64 readonly

L'identificateur unique de la source de sauvegarde (NsBackupSource) depuis laquelle il est issu.

BackupID : __int64 readonly

L'identificateur unique de la sauvegarde (NsBackup) dont il est issu.

RelativePathName : BSTR readonly

Le chemin d'accès relatif du fichier.

Size : __int64 readonly

La taille du fichier, en octets.

LastModDate : VARIANT readonly

La date de dernière modification portée par le fichier.

FileName : BSTR readonly

Le nom du fichier.

Affichage des détails sur un résultat de recherche

const THSEARCH_BACKUP_ALL = -2

Set connection = CreateObject("NsAPI.NsConnection")
Set sysutils = CreateObject("NsAPI.NsScriptUtils")

if connection.ConnectToLocalServer then
  set searchEngine = CreateObject("NsAPI.NsSearchEngine")
  searchEngine.BackupID = THSEARCH_BACKUP_ALL  ' On cherche dans toutes les sauvegardes (nécessite des droits administrateur)
  searchEngine.Limit = 1 ' 1 résultat seulement (pour la démo...)
  
  ' Faire une recherche dans la base de fichiers contenant le nom "test"
  set results = searchEngine.SearchByFileName(connection, "test", false)
  
  ' Au moins 1 résultat ?
  if results.Count > 0 then
    ' On examine le premier résultat.
    set demoResult = results(0)
    
    MsgBox "Nom du fichier : " & demoResult.FileName
    MsgBox "Taille du fichier : " & sysutils.SizeToStr(demoResult.Size)
    MsgBox "Chemin relatif du fichier : " & demoResult.RelativePathName
    
    ' Charger la source de sauvegarde pour obtenir des informations supplémentaires...
    Set backupSource = CreateObject("NsAPI.NsBackupSource")
    if not backupSource.LoadFromID(connection, demoResult.SourceID) then
      MsgBox "Impossible de charger des informations sur la source de sauvegarde."
      WScript.Quit
    end if
    
    ' Afficher le chemin complet du fichier en utilisant la fonction BuildPath()
    MsgBox "Chemin complet du fichier : " & backupSource.BuildPath(demoResult.RelativePathName)
    ' Afficher la date de dernière modification du fichier, convertie au format local :
    MsgBox "Date de dernière modification du fichier : " & backupSource.GetLocalFileDate(demoResult.LastModDate)
    
    ' Charger les informations de sauvegarde pour obtenir encore des informations supplémentaires...
    Set backup = CreateObject("NsAPI.NsBackup")
    if not backup.LoadFromID(connection, demoResult.backupID) then
      MsgBox "Impossible de charger des informations sur la sauvegarde."
      WScript.Quit
    end if
    
    ' Afficher le nom de la sauvegarde parente.
    MsgBox "Sauvegarde parente : " & backup.Name
  end if
  
else
  MsgBox "Connexion au serveur local impossible."
end if